UnFill et rotated Label

[MB]

Bonjour, en effectuant quelques recherches je suis tombé sur ce sujet, dans lequel Olivier propose la solution suivante.

Code : Tout sélectionner

size(5cm);
filldraw(scale(10)*unitcircle);
frame f;
label(f,"Test",Fill(white));
add(rotate(40)*f,(1,1),UnFill);
add(rotate(-45)*f,(-4,-4));

Je cherche à faire en sorte que le fond ne soit pas blanc, comme c'est le cas avec Fill(white), mais transparent comme c'est le cas avec UnFill. Des idées ?

[OG]

Bonsoir

J'ai un petit souci avec la transparence (plus de transparence sauf en format svg).
Aurais-tu un exemple plus parlant car si c'est transparent on ne verra pas les étiquettes ?
Sinon on peut toujours ajuster la transparence avec opacity(entre 0 et 1).

O.G.

[MB]

Par exemple, avec la figure suivante, j'ai un label option 'UnFill' mais dont le fond est transparent (et non blanc).

Code : Tout sélectionner

size(4cm);
filldraw(scale(10)*unitcircle);
label(scale(4)*"Test",(0,0),UnFill);

L'objectif serait donc d'adapter la version frame afin d'obtenir un fond transparent au lieu d'un fond blanc.

[OG]

Ok j'ai compris la question !

Mettre `Unfill` dans la définition du label ne va pas te satisfaire à mon avis. Car j'imagine que tu voudrais qu'avec une rotation on obtienne un joli rectangle transparent (qui a subi la rotation) et là ça ne marche pas.
Il y a une solution avec la routine unfill(path), mais il faut récupérer la taille et position du rectangle, ce qui prendra un peu de temps.

Code : Tout sélectionner

size(5cm);
filldraw(scale(10)*unitcircle);
frame f;
label(f,"Test",red,UnFill);
add(rotate(40)*f,(1.4,1.4),UnFill);

add(rotate(-45)*f,(-4,-4));

[OG]

Voilà, il y a peut-être plus simple. La difficulté est de récupérer le rectangle qui fait le cadre. Attention si tu ajoutes après un élément qui sort du cadre, cela change l'échelle, donc met à terre la solution proposée.

Code : Tout sélectionner

size(5cm);
filldraw(scale(10)*unitcircle);
frame f;
label(f,"Test",blue,UnFill);

add(rotate(40)*f,(1,1),UnFill);

path rh=scale(size(f).x,size(f).y)*shift(-.5,-.5)*unitsquare;
real sx=size(currentpicture,true).x/size(currentpicture,false).x;
real sy=size(currentpicture,true).y/size(currentpicture,false).y;
path rhe=scale(sx,sy)*rh;
unfill(shift(-4,-4)*rotate(-45)*rhe);
add(rotate(-45)*f,(-4,-4));

[MB]

Merci Olivier, c'est exactement ça.

En ce qui concerne la figure suivante, je me demandais d'où venait la marge entre le texte et la boite du label. J'ai pas vraiment pu déterminer si cette marge est gérée par latex ou par asymptote. J'ai tenté de mettre labelmargin=0 mais ça ne change pas grand chose, je ne suis pas parvenu à supprimer cette marge.

Code : Tout sélectionner

size(4cm);
filldraw(scale(10)*unitcircle);
label(scale(4)*"Test",(0,0),UnFill);

[OG]

Avec `object` il semble possible d'imposer une marge négative.

Code : Tout sélectionner

size(2cm);
filldraw(scale(5)*unitcircle);
//label(scale(4)*"Test",(0,0),UnFill);
object tt=draw("Test 2",box,xmargin=-2bp,ymargin=-1.5bp,(0,0),UnFill);
add(tt);

Mais il y a des surprises avec la taille.

Code : Tout sélectionner

size(2cm);
filldraw(scale(5)*unitcircle);
//label(scale(4)*"Test",(0,0),UnFill);
object tt=draw("\color{blue}Test 2",box,xmargin=-2bp,ymargin=-1.5bp,(0,0),UnFill);
add(tt);

[MB]

Merci pour les pistes.

Ce qui n'est pas très clair, c'est de savoir qui, entre latex et asymptote, ajoute cette marge. Avec le code suivant, il y a l'espace entre "Test" et la fbox, qui est bien-sûr généré par latex, mais il y a également un espace autour de la fbox. Là il me semble plus difficile de savoir qui l'a ajouté.

Code : Tout sélectionner

size(4cm);
filldraw(scale(10)*unitcircle);
label(scale(2)*"\fbox{Test}",(0,0),UnFill);