Flèches le long d'un chemin

[zariski63]

Bonjour !
Je me suis bricolé un truc qui me permet de placer des pointes de flèches sur un chemin.
Cependant, si je peux placer un nombre donné de flèches, je ne vois pas comment en placer une à un point précis du chemin...
De plus si je pouvais choisir la couleur et le fond de la flèche ce serait mieux à partir de "markpointe".
Une idée svp ? Merci

Code : Tout sélectionner

import graph;
import patterns;
import markers;
unitsize(4cm);
real f(real x) {return x^2;}
real g(real x) {return 4*x/3+2;}
path p = graph(f, -2, 2, n= 400),
     q = graph(g, -1.5, 1.5, n= 400);

frame fpointe(picture pic=currentpicture,pen fillpen=currentpen, pen drawpen=currentpen)
      { frame F;
        filldraw(F, (0,-1.5)--(4,0)--(0,1.5)--cycle, fillpen, drawpen);
        return F;
      }
markroutine mesmark = markinterval(8, scale(3)*fpointe(green,blue), true);
marker markpointe = marker(mesmark);

draw(p, red, markpointe);

[MB]

Bonjour, désolé pour la réponse un peu tardive, mais voici une proposition de code.

Code : Tout sélectionner

import graph;
import patterns;
import markers;
unitsize(4cm);
real f(real x) {return x^2;}
real g(real x) {return 4*x/3+2;}
path p = graph(f, -2, 2, n= 400),
     q = graph(g, -1.5, 1.5, n= 400);

frame fpointe(picture pic=currentpicture,pen fillpen=currentpen, pen drawpen=currentpen)
      { frame F;
        filldraw(F, (0,-1.5)--(4,0)--(0,1.5)--cycle, fillpen, drawpen);
        return F;
      }
markroutine mesmark = markinterval(8, scale(3)*fpointe(green,blue), true);
marker markpointe = marker(mesmark);

draw(p, red, markpointe);

void add_fpointe(path p, real t, pen fillpen=currentpen, pen drawpen=currentpen) {
    add(scale(3)*rotate(degrees(dir(p,reltime(p,t))))*fpointe(fillpen,drawpen),relpoint(p,t));
}

add_fpointe(p,0.25,yellow,orange);
add_fpointe(p,0.5,yellow,orange);
add_fpointe(p,0.75,yellow,orange);

[zariski63]

Bonjour,

Même si la réponse a été tardive (et c'est vraiment pas grave) j'apprécie la réponse et la compétence car c'est justement ce qu'il me fallait.

Mille merci !!
Bonne journée
E.C