Boucles while et for

[maurice]

Bonsoir, les deux codes suivants sont censés donner le même résultat. Je préfèrerais la version avec while, mais je en sais pas ou est le problème !
Pourrez vous m'éclairer ?

Version avec for :

Code : Tout sélectionner

unitsize(0.5cm);

string alph="ABCDEFGHIJKLMNOPQRSTUVWXYZ";

int[] clef_chiffree(string clef, string alphabet=alph) {
	int[] ent;
	int r=-1;
	for (int j=0; j<length(clef); ++j) {
		for (int k=0; k<length(alphabet); ++k) {
			if (substr(clef, j, 1)==substr(alphabet, k, 1)) 
				{r=k;}
				
		} 
		ent[j]=r;
	}
	return ent;
}

string clef="MATH";		
int[] a=clef_chiffree(clef);
for (int k=0; k<4; ++k) label(format("%i",a[k]), (k,-k));

Version avec while :

Code : Tout sélectionner

unitsize(0.5cm);

string alph="ABCDEFGHIJKLMNOPQRSTUVWXYZ";

int[] clef_chiffree(string clef, string alphabet=alph) {
	int[] ent;
	int r=-1;
	for (int j=0; j<length(clef); ++j) {
		int k=0;
		do {
			if (substr(clef, j, 1)==substr(alphabet, k, 1)) 
				{r=k;}
			else {k=k+1;}
		} 
		while (r==-1);
		ent[j]=r;
	}
	return ent;
}

string clef="MATH";		
int[] a=clef_chiffree(clef);
for (int k=0; k<4; ++k) label(format("%i",a[k]), (k,-k));

C'est sans doute une erreur de débutant programmeur mais bon !
Merci

Maurice

[OG]

Code : Tout sélectionner

unitsize(0.5cm);

    string alph="ABCDEFGHIJKLMNOPQRSTUVWXYZ";

    int[] clef_chiffree(string clef, string alphabet=alph) {
    int[] ent;
    int r=-1;
    for (int j=0; j<length(clef); ++j) {
    int k=0;
    r=-1;
    do {
    if (substr(clef, j, 1)==substr(alphabet, k, 1))
    {r=k;}
    else {k=k+1;}
    }
    while (r==-1);
    ent[j]=r;
    }
    return ent;
    }

    string clef="LEGOUVERNEMENTMENT";
    int[] a=clef_chiffree(clef);
    for (int k=0; k<a.length; ++k) label(format("%i",a[k]), (k,-k));

O.G.

[Tunaki]

Bonjour,

Je ne connais pas Asymptote mais je passais par là donc j'en profite pour te répondre. Le problème vient de ta condition pour rester dans le while. Après le premier tour de ta boucle sur $j$, tu as forcément $r\ne -1$ et donc tu ne peux plus entrer dans ta boucle "while" (tout du moins, une seule fois puisque tu utilises do...while, mais tu ne boucleras pas).
Tu devrais plutôt faire

Code : Tout sélectionner

do{k++;}while(!substr(clef, j, 1)==substr(alphabet, k, 1));
ent[j]=k;

Comme ça, en plus, tu n'as plus besoin de variable temporaire $r$.

[maurice]

Le problème vient de ta condition pour rester dans le while. Après le premier tour de ta boucle sur $j$, tu as forcément $r\ne -1$ et donc tu ne peux plus entrer dans ta boucle "while" (tout du moins, une seule fois puisque tu utilises do...while, mais tu ne boucleras pas).

Bon sang !!! Mais c'est bien sur !!!

Tu devrais plutôt faire

Code : Tout sélectionner

do{k++;}while(!substr(clef, j, 1)==substr(alphabet, k, 1));
ent[j]=k;

Comme ça, en plus, tu n'as plus besoin de variable temporaire $r$.

Merci beaucoup à Tunaki pour son explication et à OG pour avoir exhibé l'erreur de mon code !!!

On ne s'improvise pas programmeur !

maurice

[GMaths]

Il me semble que ceci est .... ..... (il suffit de décoder pour le savoir :-))

Code : Tout sélectionner

unitsize(0.5cm);
string alph="ABCDEFGHIJKLMNOPQRSTUVWXYZ";
string clef="PLUSCOURT";
for(int j=0; j<length(clef); ++j) {
  label(format("%i",find(alph,substr(clef,j,1),pos=1)),(j,-j));
}

[maurice]

Il me semble que ceci est .... ..... (il suffit de décoder pour le savoir :-))

Oui, mais je veux pouvoir réutiliser cette liste plus tard d'où le int[]. Je n'avais pas pensé à utiliser find, c'est à creuser ....

Merci

Maurice

[GMaths]

Oui, mais je veux pouvoir réutiliser cette liste plus tard d'où le int[]. Je n'avais pas pensé à utiliser find, c'est à creuser ....

Il suffit de demander :

Code : Tout sélectionner

unitsize(0.5cm);
string alph="ABCDEFGHIJKLMNOPQRSTUVWXYZ";
string clef="PLUSCOURT";
int[] a;
for(int j=0; j<length(clef); ++j) {
a.push(find(alph,substr(clef,j,1),pos=1));
label(format("%i",a[j]),(j,-j));
}

[maurice]

Bonsoir et merci !

Efficacité, sobriété !!!
Je crois que ca m'être utile !
encore merci

Maurice