[graph_pi] Agir sur la taille des labels

[maurice]

bonsoir, voici un repère :

Code : Tout sélectionner

import graph_pi;
graphicrules(xunit=0.5cm, yunit=0.05cm, xmin=0, xmax=10, ymin=0, ymax=100);
defaultpen(fontsize(8pt));

grid(xStep=1, xstep=0, yStep=10, ystep=0, orange);
cartesianaxis(Lx=Label("$n$",align=2SE), Ly=Label("$u_n$",align=2 E),
              xticks = Ticks(NoZero, Step=1, step=0),
              yticks = Ticks(NoZero, Step=10, step=0));

jusqu'ici pas de problème mais si on ajoute un \large dans Ly :

Code : Tout sélectionner

Ly=Label("\large $u_n$", align=2E)

le label a subit une rotation de 90 degré ...

Code : Tout sélectionner

import graph_pi;
graphicrules(xunit=0.5cm, yunit=0.05cm, xmin=0, xmax=10, ymin=0, ymax=100);
defaultpen(fontsize(8pt));
grid(xStep=1, xstep=0, yStep=10, ystep=0, orange);
cartesianaxis(Lx=Label("\large $n$",align=2SE), Ly=Label("\large $u_n$",align=4 E),
              xticks = Ticks(NoZero, Step=1, step=0),
              yticks = Ticks(NoZero, Step=10, step=0));

C'est pas que cela soit très gênant mais j'aimerais comprendre pourquoi ce phénomène ...
Où si quelqu'un peut m'expliquer comment changer la taille des label du repère en intervenant dans les ticks... je n'ai pas réussi à trouver la bonne méthode.

Merci
Maurice

[GMaths]

Bonjour,

Problème que j'avais déjà constaté : j'utilise scale.
A remarquer qu'il peut se mettre devant ou à l'intérieur du Label.

Code : Tout sélectionner

import graph_pi;
graphicrules(xunit=0.5cm, yunit=0.05cm, xmin=0, xmax=10, ymin=0, ymax=100);
defaultpen(fontsize(8pt));
grid(xStep=1, xstep=0, yStep=10, ystep=0, orange);
cartesianaxis(Lx=scale(1.5)*Label("$n$",align=2SE), Ly=Label(scale(1.5)*"$u_n$",align=4 E),
xticks = Ticks(NoZero, Step=1, step=0),
yticks = Ticks(NoZero, Step=10, step=0));

Je réalise que la version de graph_pi du forum n'est pas la dernière qui règle le problème du trait noir en haut du quadrillage.

[maurice]

Bonsoir Gaétan et merci.
maurice

[gilles]

Bonjour, en fait le Label est tourné automatiquement dès qu'il prend une place trop importante.
Pour le garder droit, on peut aussi faire comme ça :

Code : Tout sélectionner

Ly=Label(rotate(0)*"\large $u_n$", align=2E)

Sinon, si j'en crois ce que dit Gaétan, le problème du vilain trait noir disparait avec la dernière version de graph_pi ? C'est une très bonne nouvelle !

Gilles

[GMaths]

Bonjour, en fait le Label est tourné automatiquement dès qu'il prend une place trop importante.
Pour le garder droit, on peut aussi faire comme ça :

Code : Tout sélectionner

Ly=Label(rotate(0)*"\large $u_n$", align=2E)

Pour être complet sur le sujet, on peut encore ajouter que :

• qu'on peut modifier la valeur de ylabelwidth, par défaut à 2.0, pour fixer le seuil de la longueur où il y a basculement ;
• qu'on peut empêcher tous les basculements en indiquant :

  Code : Tout sélectionner

  ylabelwidth=infinity;

• Si on utilise yaxis, il y a une option spécifique possible :

  Code : Tout sélectionner

  autorotate=false

  qui est pas défaut à true.

... dit-il, après avoir triché en recherchant dans ses archives du forum officiel : j'avais oublié toutes ces possibilités.