[Lualatex] Représentation de fractions en metapost

Tout ce qui concerne le langage TeX/LaTeX et ses variantes. Ce langage est utilisable sur le forum via les balises tex.
[participation réservée aux membres inscrits]
Règles du forum
Merci de soigner la rédaction de vos messages et de consulter ce sujet avant de poster. Pensez également à utiliser la fonction recherche du forum.
MB
Administrateur
Administrateur
Messages : 7898
Inscription : samedi 28 mai 2005, 14:23
Statut actuel : Enseignant

[Lualatex] Représentation de fractions en metapost

Message non lu par MB »

Rien de très original, mais voici un nouvel exemple, permettant de représenter des fractions à l'aide de luamplib.

Code : Tout sélectionner

\documentclass{article}
\usepackage{luamplib}

\newcommand{\fraction}[3][1cm]{\mplibforcehmode\begin{mplibcode}
u := #1;
def filldraw_circle(expr c,n,k) =
    pair p[];
    p0 := center c;
    if n=k:
        fill c withcolor 0.85white;
    else:
        p1 := p0 shifted (u,0);
        p2 := p1 rotatedaround(p0,k*360/n);
        fill buildcycle(p0--p1,c,p0--p2) withcolor 0.85white;
    fi;
    for i=1 upto n:
        p1 := p0 shifted (u,0) rotatedaround(p0,i*360/n);
        draw p0--p1;
    endfor;
    draw c withpen pencircle scaled 1bp;
enddef;
def fraction(expr a,b) =
    q := a div b;
    r := a mod b;
    path c;
    for n=1 upto q:
        c := fullcircle scaled 2u shifted (2.2*n*u,0);
        filldraw_circle(c,b,b);
    endfor;
    if r>0:
        c := fullcircle scaled 2u shifted (2.2*(q+1)*u,0);
        filldraw_circle(c,b,r);
    fi;
enddef;
beginfig(1); fraction(#2,#3); endfig; \end{mplibcode}}

\begin{document}

\begin{center}
\begin{tabular}{cccc}
\fraction{2}{3} & \fraction{3}{4} & \fraction{7}{5} & \fraction{9}{8} \\[5pt]
$\frac{2}{3}$ & $\frac{3}{4}$ & $\frac{7}{5}$ & $\frac{9}{8}$
\end{tabular}
\end{center}

\end{document}
fractions_luamplib.png
MB. (rejoignez pCloud et bénéficiez de 10Go de stockage en ligne gratuits)
Pas d'aide en message privé. Merci de consulter ce sujet avant de poster votre premier message.
projetmbc
Utilisateur chevronné
Utilisateur chevronné
Messages : 2150
Inscription : samedi 29 décembre 2007, 00:58

Re: [lualatex] Exemples d'utilisation

Message non lu par projetmbc »

On n'est plus vraiment dans du Lua mais cela reste intéressant.
MB
Administrateur
Administrateur
Messages : 7898
Inscription : samedi 28 mai 2005, 14:23
Statut actuel : Enseignant

Re: [lualatex] Exemples d'utilisation

Message non lu par MB »

Effectivement, pas de code lua ici, mais un usage de lualatex via luamplib (et donc du code metapost).
MB. (rejoignez pCloud et bénéficiez de 10Go de stockage en ligne gratuits)
Pas d'aide en message privé. Merci de consulter ce sujet avant de poster votre premier message.